初回起動プログラム

サンプルキャラクター「未樹」を使って，初回起動時の動作スクリプトを書いてみました。

あえてユーザーのインフォメーションダイアログを使わずに，ユーザー情報を登録できるように書いてみました。性別と年齢層の設定をすることで，違ったアクションを起こすようにしています。もっとフラグを増やせば，さまざまな反応が楽しめるようになると思います。

やっと綾織ソースの書き方に慣れてきて，コンパイル時にエラーコードが出ることが少なくなってきました。

以下に今回書いたソースを掲載しておきます。

＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝
action StartUp@(false)

{

LoadBitmap("normal.hp3");
DisplayImage(2);

Talk( "あ，\sはじめまして！\s\nあたしは，あなたの話し相手になるために作られたデスクトップ用マスコット\s「未樹」と申します。これからよろしくお願いましますね。\c");

int Flag1 = 0;
Talk( "\eまずはじめにお名前を教えてくださいね。" );
string F_Name ="名無しの";
PutProperty("F_Name",F_Name);
string L_Name ="権兵衛";
PutProperty("L_Name",L_Name);

while(Flag1 == 0)
{

Talk( "\n■名字" );
F_Name = EditBox( 0, 16, "");
PutProperty("F_Name",F_Name);
Talk( GetProperty("F_Name"));
Talk( "\n■下のお名前" );
L_Name = EditBox( 0, 16, "");
PutProperty("L_Name",L_Name);
Talk( GetProperty("L_Name"));

Talk( "\w\e" +GetProperty("F_Name") + GetProperty("L_Name") +"さんですね。" );

AddItem("そうです")
{Flag1 = 1;}
AddItem("ちがいます")
{Talk( "\eもう一度名前を入力してくださいね。" );}
Choice;
}

int Flag2 = 0;
string Sexflag;
Talk( "\e性別はどっちですか？" );

while(Flag2 == 0)
{
AddItem("男性")
{Sexflag = "男";
PutProperty("Sexflag",Sexflag);
}
AddItem("女性")
{Sexflag = "女";
PutProperty("Sexflag",Sexflag);
}
Choice;

Talk(GetProperty("Sexflag") + "の方ですね？");

AddItem("そうだよ")
{Flag2 = 1;}
AddItem("いいえ…")
{Talk( "\eもう一度性別を教えてくださいね。" );}
Choice;
}

int Flag3 = 0;
string Yearsold;
Talk( "\e年令はおいくつぐらい何ですか？" );

while(Flag3 == 0)
{
AddItem("15才未満")
{Yearsold = "16才未満";
PutProperty("Yearsold",Yearsold);
if(Sexflag == "男")
{Talk("\eあたしにも弟ができたみたいで嬉しいな。ホントのお姉ちゃんみたいに甘えてくださいね。");}
else
{Talk("\eあたしにも妹ができたみたいで嬉しいな。お姉ちゃんって呼んでもいいですよ。");}
}
AddItem("16～18才")
{Yearsold = "16～18才";
PutProperty("Yearsold",Yearsold);
if(Sexflag == "男")
{Talk("\e同世代なんですね！\s\nお友達として仲良くしていきましょうね。");}
else
{Talk("\eあたしって，同世代の女の子の友達，少ないんですよ。\s\n仲良くしてくださいね！");}
}
AddItem("19～34才")
{Yearsold = "19～34才";
PutProperty("Yearsold",Yearsold);
if(Sexflag == "男")
{Talk("\eなんか，あたしにお兄ちゃんができたみたいで，ちょっとドキドキです。ずっとお兄ちゃんが欲しかったんですよ。恥ずかしいような，嬉しいような…");}
else
{Talk("\eなんか，あたしにお姉ちゃんができたみたいで，ちょっとドキドキです。ずっとお姉ちゃんが欲しかったんですよ。恥ずかしいような，嬉しいような…");}
}
AddItem("35才以上")
{Yearsold = "30才以上";
PutProperty("Yearsold",Yearsold);
Talk("\eあたし，大人の人と話しをするのが好きなんですよ。自分の知らないことをいっぱい教えてくれるし，冷静に物を判断してくれるし…。あたしにはお父さんもお母さんもいないから，親子みたいに仲良くして欲しいです。ってちょっとずうずうしいかな…");
}
Choice;
Flag3 = 1;
}

Talk("\c\e何て呼んだらいいですか？" );
int Flag4 = 0;
string User_Called;

while(Flag4 == 0)
{

if(Sexflag == "男")
{
AddItem(GetProperty("L_Name") +"さん")
{PutProperty("User_Called",GetProperty("L_Name") +"さん");}
AddItem(GetProperty("L_Name") +"くん")
{PutProperty("User_Called",GetProperty("L_Name") +"くん");}
AddItem("お兄ちゃん")
{PutProperty("User_Called","お兄ちゃん");}
AddItem("ご主人様")
{PutProperty("User_Called","ご主人様");}
AddItem("その他")
{User_Called = EditBox( 0, 16, "");
PutProperty("User_Called",User_Called);}
Choice;
}

else
{
AddItem(GetProperty("L_Name") +"さん")
{PutProperty("User_Called",GetProperty("L_Name") +"さん");}
AddItem(GetProperty("L_Name") +"ちゃん")
{PutProperty("User_Called",GetProperty("L_Name") +"ちゃん");}
AddItem("お姉ちゃん")
{PutProperty("User_Called","お姉ちゃん");}
AddItem("その他")
{User_Called = EditBox( 0, 16, "");
PutProperty("User_Called",User_Called);}
Choice;
}

Talk(GetProperty("User_Called") + "って呼びますね？");

AddItem("いいよ")
{Flag4 = 1;}
AddItem("うーん，やっぱり…")
{Talk( "\eえ，じゃあ，何て呼んだらいいですか？" );}
Choice;

}

Talk("\e\wこれから，よろしくね，" +GetProperty("User_Called")+ "！");

}